What I do Here:-
=-=-=-=-=-=-=-=-=-=-=-=
( Educational Aspects )

We have here may class rooms with identical hardware and software requirements
Thankfully we have 5 new rooms with the same hardware and software.

We use Ghost to image the HDD onto the network.
After the Ghost file is ghosted back onto the system;
-the PC logs in as a special user
-the login script detect this user and runs a batch file
-this batch file makes Registry updates then forces a reboot

After the Reboot the PC reads the new user name to login with from the Registry.

Autoit2 is the program that I use to login.
Because it is called by the Registry is uses parameters in the Registry.

=-=-=-=-=-=-=-=
  Like This:-
=-=-=-=-=-=-=-=

Login script:-
==============
IF LOGIN_NAME = "17900" THEN INCLUDE SYS:LOGIN\DELX.INC

sys:login\delx.inc:-  ( part of )
====================
IF P_STATION="00C04FC0DCE2" THEN EXIT"X:DELX 179 01"
IF P_STATION="00C04FC0DA6A" THEN EXIT"X:DELX 179 02"
IF P_STATION="00C04FC0DC89" THEN EXIT"X:DELX 180 17"
IF P_STATION="00C04FC0D9E7" THEN EXIT"X:DELX 216 24"

x:\delx.bat:-
=============
@echo off
echo Setting up the Login Name & PC Advertising Name on the Computer.
SET RM=%1
SET PC=%2
x:\kixtart\kix32 x:\kixtart\delx.kix
copy x:\pcfix\root\firstbkp.dat c:\autoexec.bat
echo  *!*  Please wait for the computer to restart  *!*
delay 2
x:\batch\bigecho ReStarting
delay 5
x:\kixtart\shutdown.exe /force /reboot

delx.kix:-  ( part of )
==========
WRITEVALUE("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\RunServices","Login",
"c:\windows\autoit2.exe c:\windows\autolog.aut /p %RM% %PC%","REG_SZ")

c:\windows\autolog.aut:-
========================
SetKeyDelay, 1
WinWaitActive, Novell
Send, .%1%%2%.Rm%1%.student.mycontext
Send, {tab}
Send, {enter}
Exit

=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
So after all that you get:-
=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunServices,Login,
c:\windows\autoit2.exe c:\windows\autolog.aut /p 179 02

And Autoit uses the two Parameters as %1% and %2% so you login as....

.17902.rm179.student.mycontext

As long as you have done this as well:-
HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Network,DisablePwdCaching,1
HKLM\System\CurrentControlSet\Services\NOVELLNP\NetworkProvider,DisplayLastUserName,0

This took me a very long time to put together , but now it was WELL worth it !

- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

I Also play with the Registry to stop Students mucking up the Desktop settings and the like.

That is what copy "x:\pcfix\root\firstbkp.dat c:\autoexec.bat" does

firstbkp.dat:-
==============
@echo off
SET PATH=C:\WINDOWS;C:\WINDOWS\COMMAND;C:\
SET TEMP=C:\WINDOWS\TEMP
attrib -r -s -h c:\windows\user.dat
attrib -r -s -h c:\windows\system.dat
attrib -r -s -h c:\windows\win.ini
attrib -r -s -h c:\windows\system.ini
copy c:\windows\user.dat c:\windows\fonts > nul
copy c:\windows\system.dat c:\windows\fonts > nul
copy c:\windows\win.ini c:\windows\fonts > nul
copy c:\windows\system.ini c:\windows\fonts > nul
attrib +r +s +h c:\windows\user.dat
attrib +r +s +h c:\windows\system.dat
SET BLASTER=A220 I5 D1 T4
lh c:\windows\command\doskey.com /file:c:\windows\command\alist.txt
SET PATH=C:\Novell\Client32;%PATH%
Set NWLANGUAGE=ENGLISH
win

MSDOD.SYS:-   (  this means that the last line of the Autoexec.bat has to be: win )
===========
BootGUI=0

After the reboot the user logins for the first time with the Registry the way it should be,
So as they login they get a new Autoexec.bat:-
This means that no matter what they do after a reboot the Registry is restored from a backup.
==============================================
@echo off
SET PATH=C:\WINDOWS;C:\WINDOWS\COMMAND;C:\
SET TEMP=C:\WINDOWS\TEMP
attrib -r -s -h c:\windows\user.dat
attrib -r -s -h c:\windows\system.dat
attrib -r -s -h c:\windows\win.ini
attrib -r -s -h c:\windows\system.ini
copy c:\windows\fonts\user.dat c:\windows > nul
copy c:\windows\fonts\system.dat c:\windows > nul
copy c:\windows\fonts\win.ini c:\windows > nul
copy c:\windows\fonts\system.ini c:\windows > nul
attrib +r +s +h c:\windows\user.dat
attrib +r +s +h c:\windows\system.dat
SET BLASTER=A220 I5 D1 T4
lh c:\windows\command\doskey.com /file:c:\windows\command\alist.txt
SET PATH=C:\Novell\Client32;%PATH%
Set NWLANGUAGE=ENGLISH
del c:\windows\system\*.scr > nul
del c:\windows\*.bmp > nul
del c:\*.bmp > nul
win

I use the Fonts folder because; Windows will not let you see things in it unless they are fonts.
Try it; Open a DOS Box and edit a text file and create a sub dir under c:\windows\fonts
Use file find and Explorer to look for them , you won't be able to find them !


Have Fun , Josh

- - - - - - - - 

PS:- We still use VLM DOS boot disks to access the network to reghost ( bring down )
a ghost image in the Rooms without Boot ROMs.

That is automated too.

Boot Disk :-
============
set dellboot=yes
login ghoster /nb

Login script:-   ( < thing > is the test for a Dos Set Variable )
==============
IF <DELLBOOT> = "YES" THEN EXIT"X:\GDELMNU.BAT"

x:\gdelmnu.bat:-
================
@echo off
cls
type x:\gdelmnu.txt
map root p:=sys:student\ghost\images > nul
p:
x:\choice /C:NFQ /T:N,10 /N "Your Selection :- "
Rem   N is Normal for D: to C: , F is for Force from the network , Q is for Quit
echo.
if errorlevel 3 goto end
if errorlevel 2 goto nfce
if errorlevel 1 goto nml
:nfce
ghost -rb -sure -clone,mode=load,src=p:\dell.img,dst=1
x:
map del p: > nul
goto end
:nml
if not exist d:\dell.img goto nfce
ghost -rb -sure -clone,mode=pload,src=d:\dell.img:1,dst=1:1
x:
map del p: > nul
:end
x:
echo Thank You...
echo.
-----------------------------------------------
You may have noticed that I love Batch Files...